模拟某楼层浇注

发布日期:[08-12-04 13:39:20] 浏览人次:[]

如图所示楼层,实际施工中为分块浇注。首先浇注中间部分(红色),然后浇注支撑处部分(黑色)。

利用ANSYS的单元生死功能,对问题进行仿真。
第一步:整过模架在重力作用下的变形。

浇注模拟命令流:
FINISH
/CLEAR,NOSTART
/PREP7
ET,1,BEAM3
ET,2,PLANE42
R,1,0.25,1E-2,0.5
MP,EX,1,210E9
MP,NUXY,1,0.3
MP,DENS,1,7800
MP,EX,2,210E9
MP,NUXY,2,0.3
MP,DENS,2,24000
*DO,IK,1,3
*DO,IP,1,17
N,IP+(IK-1)*17,(IP-1)*5,10-(IK-1)*5
*ENDDO
*ENDDO
*DO,IK,1,2
*DO,IP,1,5
N,IP+51+(IK-1)*5,(IP-1)*20,-(IK*10)
*ENDDO
*ENDDO
*DO,IP,1,16
TYPE,1
MAT,1
REAL,1
E,34+IP,35+IP
TYPE,2
MAT,2
E,IP,IP+1,IP+18,IP+17
E,IP+17,IP+18,IP+35,IP+34
*ENDDO
TYPE,1
MAT,1
REAL,1
E,35,52
E,52,57
E,39,53
E,53,58
E,43,54
E,54,59
E,47,55
E,55,60
E,51,56
E,56,61
/SOLU
ANTYPE,STATIC
TIME,1
NLGEOM,ON
NROPT,FULL
ESTIF,1E-8
ESEL,S,TYPE,,2
EKILL,ALL
ESEL,S,LIVE
NSLE,S
NSEL,INVE
D,ALL,ALL
NSEL,ALL
ACEL,,9.81
NSEL,S,LOC,Y,-20
D,ALL,ALL
ALLSEL,ALL
SOLVE
TIME,2
ESEL,S,TYPE,,2
EALIVE,ALL
NSEL,S,LOC,Y,5,12
DDELE,ALL
ALLSEL,ALL
SOLVE
/POST1
/DSCALE,1,AUTO
PLDISP,0
PLNSOL, S,EQV, 0,1.0

上面给出的是一次模拟和浇注模拟相应的命令流。在浇注模拟中需注意的问题:
(1)所有模型(单元),必须在前处理建立,包括所有后来浇注的部分及杀死的部分。
(2)分成两个载荷步进行求解计算,对应步骤相应进行单元的生死处理。各载荷步求解之间不能推出Solution求解器!
(3)求解过程中要打开大变形开关、应用牛顿-拉斐逊算法(ANSYS单元生死必须的)。

对这两种分析方案的比较:
(1)一次模拟:一次性生成结构,然后分析结构在自重下的变形。 优点:方便快捷。缺点:一次模拟方法纯粹是从结构分析的角度考虑,不考虑结构的施工过程对结构的影响。结果有一定误差,特别对土建结构,施工过程往往对最终结构的应力分布产生较大的影响。
(2)浇注模拟:先生成支撑模架,然后再生成上层混凝土,然后分析结构在自重下的变形。优点:考虑了结构施工过程对结构最终内力分布的影响。结果较精确,对土建结构,施工过程往往对最终结构的应力分布产生较大的影响,建议采用。缺点:模拟过程复杂,对技术人员要求较高。

www.mapeng.net 马棚网
www.mapeng.net
文章作者:未知 | 文章来源:网络 | 责任编辑:admin | 发送至邮箱: | 加入收藏:
本文关键字:模拟  楼层  浇注
上一篇:滞回分析
下一篇:Moldflow软件介绍
相关资讯
热点资讯
推荐资讯

关于我们 | 站点导航 | 使用帮助 | 友情链接 | 广告服务 | 免责声明 | 新手上路
设为首页 | 加入收藏 | 在线留言 | 马棚网QQ群:{92562572}{102901272}{333259257} | 交流QQ: 客户服务 客户服务 客户服务