简支梁实体与预应力钢筋分析实例

发布日期:[08-12-04 12:31:18] 浏览人次:[]

/COM, Structural
/PREP7
egjx=2e5 !Ey
agjx=140 !单根钢绞线面积
ehnt=4e4 !Eh
xzxs=1.0e-5 !线胀系数
yjl=200000 !定义预加力
et,1,link8 !定义link8单元
et,2,solid95 !定义solid95单元
r,1,agjx !定义link8单元的面积
r,2 !定义第2种实常数
mp,ex,1,egjx !定义link8单元的弹性模量
mp,prxy,1,0.3 !定义link8单元的泊松系数
mp,alpx,1,1.0e-5 !定义线膨胀系数
mp,ex,2,ehnt !定义solid95单元的弹性模量
mp,prxy,2,0.3 !定义solid95单元的泊松系数
blc4, , ,100,200,3000 !定义梁体
/view,1,1,1,1 !定义ISO查看
/ang,1
vplot !绘制梁体
kwpave,6 !工作平面移动到关键点6
wpoff,-30 !工作平面移动-30mm(X)
wprot,0,0,90 !工作平面旋转
vsbw,1 !分割梁体
wpoff,0,0,-40 !工作平面移动-40mm(Z)
vsbw,2 !分割梁体
wpoff,0,40 !工作平面移动40mm(Y)
wprot,0,90 !工作平面旋转
vsbw,all !分割梁体
wpstyl !关闭工作平面显示
nummrg,all,,,,low !整理
numcmp,all !压缩编号
esize,30 !定义网分时边长控制
lsel,s,,,28,38,10 !定义line28和38为新的选择集
latt,1,1,1 !定义选择集的属性
lmesh,all !对线划分单元
allsel,all !新的选择集为所有的实体
gplot !绘制所有的实体
vsel,s,,,all !定义所有体为选择集
vatt,2,2,2 !定义选择集的属性
mshape,0,3d !将体划分单元的形状定位HEX
mshkey,1 !采用MAPPED划分器
vmesh,all !对体进行划分单元
finish
/solu
dl,3,,all !对线line7施加约束(UX,UY,UZ)
dl,16,,all !对线line31施加约束(UX,UY,UZ)
dl,23,,all !对线line23施加约束(UX,UY,UZ)
dl,2,,uy !对线line4施加约束(UY)
dl,15,,uy !对线line30施加约束(UY)
dl,22,,uy !对线line23施加约束(UY)
dk,2,,,,,ux,uy !对关键点2约束(UX,UY)
bfl,28,temp,-yjl/(xzxs*egjx*agjx) !对钢绞线施加温度
bfl,38,temp,-yjl/(xzxs*egjx*agjx) !对钢绞线施加温度
solve !求解
finish
/post1
plnsol,s,z,0,1 !绘制Z方向的应力
etable,sigi,ls,1 !定义钢筋单元数据表
plls,sigi,sigi,1 !绘制上述应力
!finish
!/exit,nosav www.mapeng.net 马棚网
www.mapeng.net
文章作者:未知 | 文章来源:网络 | 责任编辑:admin | 发送至邮箱: | 加入收藏:
本文关键字:简支梁  实体  预应力  钢筋  分析  实例
相关资讯
热点资讯
推荐资讯

关于我们 | 站点导航 | 使用帮助 | 友情链接 | 广告服务 | 免责声明 | 新手上路
设为首页 | 加入收藏 | 在线留言 | 马棚网QQ群:{92562572}{102901272}{333259257} | 交流QQ: 客户服务 客户服务 客户服务